欧冠

如何用保存数据库连接参数代码及祥解

2019-09-13 20:47:38来源:励志吧0次阅读

在设计数据库应用程序的时候,经常需要将一些信息从程序中独立出来,以保证程序的可移植性。其中最重要的信息就是数据库的连接参数。

在Delphi中,获得正确的数据库连接参数的方法十分简单,你只需要建立一个数据模块,在其中添加一个ADO Connection,双击之,然后在弹出的窗口中选“Use Connection String”,单击“Build”按钮,在“数据链接属性”窗口中选择适当的驱动引擎,并设定相应的连接参数就可以了。点击“确认”后,系统将自动生成连接串,显示在Object Inspector的Connection String中。

以Microsoft SQL Server 为例,连接串就类似于:

Provider=SQLOLEDB.1;Password=map;Persist Security Info=True;User ID=map;Initial Catalog=SuperWorkFlow;Data Source=GTSERVER

连接串中各项参数由分号(;)分隔,具体含义如下:

Provider ―― 驱动类型

Data Source ―― 服务器名称

Initial Catalog ―― 数据库名称

User ID ―― 用户名

Password ―― 口令

Persist Security Info ―― 是否使用持续安全验证

现在我们所要做的第一件工作是将各项参数写入一个INI文件中。

Windows INI文件,可解释为Windows初始化文件。它是一种专门用来保存应用程序初始化信息和运行环境信息的文本文件。例如Windows 3.1中两个著名的INI文件win.ini和system.ini就在Windows启动时定义了Windows环境中鼠标响应速度、使用的外壳(shell)程序等设置,Windows系统附带的许多应用程序也都有自己的INI文件。Windows软件初始化参数的获取与保存是通过读取扩展名为INI的文本文件实现的,即程序运行前先从制定的INI文件中搜索到所需的参数,并反映到程序的运行环境中,当程序退出时又将当前的环境参数保存到制定的INI文件中。

INI文件是文本文件,由若干section组成,在每个带括号的标题下面,是若干个Keyword和一个等号,每个Keyword会控制应用程序某个功能的工作方式,等号右边的Value制定Keyword的操作方式,其一般形式如下:

[section1]

keyword1=value1

keyword2=value2

[section2]

keyword1=value1

keyword2=value2

其中SectionName和KeywordName分别是段名和关键字明,Value为关键字对应的设定值,如果等号右边无任何内容(value为空),表示Windows应用程序已为该Keyword指定了缺省值,如果在整个文件中找不到某个Keyword,同样表示为它们指定了缺省值,各Section所出现的顺序是无关紧要的,在每一个Section里,各个Keyword的顺序同样也无关紧要,Keyword的值的类型多为String或Integer,应分两种情况读写。

INI文件的书写有严格的要求:

1、Section的名称必须加以“[”和“]”,且“[”必须在屏幕的第一列。

2、Keyword名称也必须从屏幕的第一列开始书写,且后面必须紧跟“=”

3、可以对文件加以注释,每行注释须以“;”开头。

依照上述规则,我们编写下面的INI文件存储数据库的连接信息:

[dbParam]

Data Source=GTSERVER

Initial Catalog=SuperWorkFlow

User ID=map

Password=map

下面要做的工作就是编写代码,在程序执行的时候从INI文件中读取数据库连接参数,为此,我编写了下面的代码:

//RWini.pas

unit RWini;

interface

uses INIFiles;

const strINIname = 'db.ini';//INI文件的文件名,大家根据具体情况修改

var

iniParam : TINIFile;

strLocal : String;

procedure readParam(out server:String;out database:string;out user:string;out password:string);

procedure writeParam(server:string;database:string;user:string;password:string);

function getConnStr:string;

implementation

procedure readParam(out server:String;out database:string;out user:string;out password:string);

begin

//从配置文件中读取数据库连接参数

server := iniParam.ReadString('dbParam','Data Source','');

database := iniParam.ReadString('dbParam','Initial Catalog','');

user := iniParam.ReadString('dbParam','User ID','');

password := iniParam.ReadString('dbParam','Password','');

end;

procedure writeParam(server:string;database:string;user:string;password:string);

begin

//将数据库连接参数写入配置文件

iniParam.WriteString('dbParam','Data Source',server);

iniParam.WriteString('dbParam','Initial Catalog',database);

iniParam.WriteString('dbParam','User ID',user);

iniParam.WriteString('dbParam','Password',password);

end;

function getConnStr:String;

var

server,database,user,password : String;

begin

//生成数据库连接串

readParam(server,database,user,password);

result := 'Provider=SQLOLEDB.1;Password=' + password + ';Persist Security Info=True;User ID=' + user + ';Initial Catalog=' + database + ';Data Source=' + server;

end;

initialization

getDir(0,strLocal);

iniParam := TINIFile.Create(strLocal + '' + strINIname);

finalization

iniParam.Free;

end.

在程序数据模块的Create事件中添加下面的代码:

procedure TDM.DataModuleCreate(Sender: TObject);

var

confForm : TConf;

begin

conn.ConnectionString := RWini.getConnStr;

try

conn.Open;

except

on Err : EOLEException do

begin

confForm := TConf.Create(self);

confForm.ShowModal;

end;

end;

end;

这样,在程序执行过程中,将自动从INI文件中读取数据库连接参数,连接数据库,如果连接出现错误,将显示参数配置窗口,让用户配置数据库连接参数。配置窗口的代码如下:

//上面的代码省略

uses RWini;

{$R *.dfm}

procedure TConf.FormShow(Sender: TObject);

var

sServer,sDatabase,sUser,sPassword : String;

begin

readParam(sServer,sDatabase,sUser,sPassword);

self.edtServer.Text := sServer;

self.edtDatabase.Text := sDatabase;

self.edtUser.Text := sUser;

self.edtPassword.Text := sPassword;

self.ActiveControl := self.btnOK;

end;

procedure TConf.btnCancelClick(Sender: TObject);

begin

close;

end;

procedure TConf.btnOKClick(Sender: TObject);

var

sServer,sDatabase,sUser,sPassword : String;

begin

sServer := self.edtServer.Text;

sDatabase := self.edtDatabase.Text;

sUser := self.edtUser.Text;

sPassword := self.edtPassword.Text;

writeParam(sServer,sDatabase,sUser,sPassword);

close;

end;

查看本文来源

小孩咳嗽吃什么药
宝宝消化不良又吐又拉
治疗便秘用什么中药
薏芽健脾凝胶作用
分享到: